pw_graphics/pw_display/BUILD.gn

# Copyright 2024 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_sync/backend.gni")
import("$dir_pw_unit_test/test.gni")

declare_args() {
  # Enable nearest-neighbor display resizing, during display update, if the
  # framebuffer size does not match the display driver size.
  pw_display_DISPLAY_RESIZE = "0"
}

config("public_include_path") {
  include_dirs = [ "public" ]
  visibility = [ ":*" ]
}

config("build_config") {
  cflags = [ "-DDISPLAY_RESIZE=" + pw_display_DISPLAY_RESIZE ]
  visibility = [ ":*" ]
}

pw_test_group("tests") {
  tests = [ ":display_test" ]
}

pw_source_set("pw_display") {
  public_configs = [
    ":build_config",
    ":public_include_path",
  ]
  public = [ "public/pw_display/display.h" ]
  sources = [ "display.cc" ]
  public_deps = [
    "$dir_pw_assert",
    "$dir_pw_status",
    "$dir_pwexperimental_color",
    "$dir_pwexperimental_display_driver",
    "$dir_pwexperimental_framebuffer",
    "$dir_pwexperimental_framebuffer_pool",
    "$dir_pwexperimental_geometry",
  ]
}

pw_test("display_test") {
  enable_if = pw_sync_COUNTING_SEMAPHORE_BACKEND != ""
  sources = [ "display_test.cc" ]
  deps = [ ":pw_display" ]
}

pw_doc_group("docs") {
  sources = [ "docs.rst" ]
}