blob: ba1a70893de348cc4850351cf32ebd127c80f84e [file] [log] [blame]
# Copyright 2021 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
# https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.
import("//build_overrides/pigweed.gni")
import("$dir_pw_build/exec.gni")
import("$dir_pw_malloc/backend.gni")
# Executable wrapper that includes some baremetal startup code.
template("mimxrt595_executable") {
group(target_name) {
deps = [
":${target_name}__binary",
":${target_name}__elf",
]
}
# .elf binary created by the standard toolchain.
_base_target_name = target_name
executable("${target_name}__elf") {
output_name = "${_base_target_name}"
forward_variables_from(invoker, "*")
if (!defined(deps)) {
deps = []
}
deps += [ "//targets/mimxrt595_evk:boot" ]
if (pw_malloc_BACKEND != "") {
if (!defined(configs)) {
configs = []
}
configs += [ "$dir_pw_malloc:pw_malloc_wrapper_config" ]
}
}
# .bin binary created by extracting from the toolchain output.
pw_exec("${target_name}__binary") {
if (defined(invoker.output_dir)) {
_output_dir = invoker.output_dir
} else {
_output_dir = target_out_dir
}
outputs = [ "${_output_dir}/${_base_target_name}.bin" ]
deps = [ ":${_base_target_name}__elf" ]
program = "arm-none-eabi-objcopy"
args = [
"-Obinary",
"<TARGET_FILE(:${_base_target_name}__elf)>",
rebase_path(outputs[0], root_build_dir),
]
}
}