# Copyright 2021 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/python.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_rpc/internal/integration_test_ports.gni")

pw_python_package("py") {
  generate_setup = {
    metadata = {
      name = "pw_transfer"
      version = "0.0.1"
    }
  }
  sources = [
    "pw_transfer/__init__.py",
    "pw_transfer/client.py",
    "pw_transfer/transfer.py",
  ]
  tests = [ "tests/transfer_test.py" ]
  python_deps = [
    "$dir_pw_rpc/py",
    "$dir_pw_status/py",
  ]
  python_test_deps = [ "$dir_pw_build/py" ]
  pylintrc = "$dir_pigweed/.pylintrc"
  proto_library = "..:proto"
}

pw_python_script("python_cpp_transfer_test") {
  sources = [ "tests/python_cpp_transfer_test.py" ]
  python_deps = [
    ":py",
    "$dir_pw_hdlc/py",
    "$dir_pw_rpc/py",
    "$dir_pw_status/py",
    "..:test_server_proto.python",
  ]
  pylintrc = "$dir_pigweed/.pylintrc"

  action = {
    args = [
      "--port=$pw_transfer_PYTHON_CPP_TRANSFER_TEST_PORT",
      "--test-server-command",
      "<TARGET_FILE(..:test_rpc_server)>",
    ]
    deps = [ "..:test_rpc_server" ]
    stamp = true
  }
}