# Copyright 2022 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pi_pico.gni")
import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")

# TODO(amontanez): This can go away if the GN build can be upstreamed to the
# Pi Pico repo.
_CWD = "${PICO_SRC_DIR}/src/rp2_common/hardware_clocks"

config("public_include_dirs") {
  include_dirs = [ "${_CWD}/include" ]
}

pw_source_set("hardware_clocks") {
  remove_configs = [ "$dir_pw_build:strict_warnings" ]
  public_configs = [ ":public_include_dirs" ]
  public = [ "${_CWD}/include/hardware/clocks.h" ]
  public_deps = [
    "${PICO_ROOT}/src/common/pico_base",
    "${PICO_ROOT}/src/rp2040/hardware_structs",
  ]
  deps = [
    "${PICO_ROOT}/src/rp2040/hardware_regs",
    "${PICO_ROOT}/src/rp2040/hardware_regs:platform_defs",
    "${PICO_ROOT}/src/rp2_common/hardware_gpio",
    "${PICO_ROOT}/src/rp2_common/hardware_irq",
    "${PICO_ROOT}/src/rp2_common/hardware_pll",
    "${PICO_ROOT}/src/rp2_common/hardware_watchdog",
    "${PICO_ROOT}/src/rp2_common/hardware_xosc",
  ]

  # hardware_pll and hardware_clocks circularly depend on each other.
  # hardware_xosc and hardware_clocks circularly depend on each other.
  allow_circular_includes_from = [
    "${PICO_ROOT}/src/rp2_common/hardware_pll",
    "${PICO_ROOT}/src/rp2_common/hardware_xosc",
  ]

  sources = [ "${_CWD}/clocks.c" ]
}