# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("$dir_pw_docgen/docs.gni")
import("$dir_pw_unit_test/test.gni")

config("default_config") {
  include_dirs = [ "public" ]
}

group("pw_allocator") {
  deps = [
    ":block",
    ":freelist",
    ":freelist_heap",
  ]
}

source_set("block") {
  public_configs = [ ":default_config" ]
  public = [ "public/pw_allocator/block.h" ]
  public_deps = [
    "$dir_pw_span",
    "$dir_pw_status",
  ]
  sources = [ "block.cc" ]
}

source_set("freelist") {
  public_configs = [ ":default_config" ]
  public = [ "public/pw_allocator/freelist.h" ]
  public_deps = [
    "$dir_pw_containers",
    "$dir_pw_span",
    "$dir_pw_status",
  ]
  sources = [ "freelist.cc" ]
}

source_set("freelist_heap") {
  public_configs = [ ":default_config" ]
  public = [ "public/pw_allocator/freelist_heap.h" ]
  public_deps = [
    ":block",
    ":freelist",
    "$dir_pw_span",
  ]
  sources = [ "freelist_heap.cc" ]
  sources += public
}

pw_test_group("tests") {
  tests = [
    ":block_test",
    ":freelist_test",
    ":freelist_heap_test",
  ]
}

pw_test("block_test") {
  deps = [ ":block" ]
  sources = [ "block_test.cc" ]
}

pw_test("freelist_test") {
  deps = [ ":freelist" ]
  sources = [ "freelist_test.cc" ]
}

pw_test("freelist_heap_test") {
  deps = [ ":freelist_heap" ]
  sources = [ "freelist_heap_test.cc" ]
}

pw_doc_group("docs") {
  sources = [ "docs.rst" ]
}