third_party/pico_sdk/src/common/pico_stdlib/BUILD.gn

# Copyright 2022 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pi_pico.gni")
import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")

# TODO(amontanez): This can go away if the GN build can be upstreamed to the
# Pi Pico repo.
_CWD = "${PICO_SRC_DIR}/src/common/pico_stdlib"

import("pico_stdio.gni")

config("public_include_dirs") {
  include_dirs = [ "${_CWD}/include" ]
  defines = [ "${PICO_STDIO}=1" ]
}

pw_source_set("headers") {
  public_configs = [
    "${PICO_ROOT}/gn:disable_warnings",
    ":public_include_dirs",
  ]
  public_deps = [
    "${PICO_ROOT}/src/common/pico_base",
    "${PICO_ROOT}/src/common/pico_time",
    "${PICO_ROOT}/src/rp2_common/hardware_gpio",
    "${PICO_ROOT}/src/rp2_common/hardware_uart",
    "${PICO_ROOT}/src/rp2_common/pico_stdio",
  ]

  if (PICO_STDIO == ENUM_LIB_PICO_STDIO.UART) {
    public_deps += [ "${PICO_ROOT}/src/rp2_common/pico_stdio_uart" ]
  } else if (PICO_STDIO == ENUM_LIB_PICO_STDIO.USB) {
    public_deps += [ "${PICO_ROOT}/src/rp2_common/pico_stdio_usb" ]
  } else if (PICO_STDIO == ENUM_LIB_PICO_STDIO.SEMIHOSTING) {
    public_deps += [ "${PICO_ROOT}/src/rp2_common/pico_stdio_semihosting" ]
  }

  public = [ "include/pico/stdlib.h" ]
}

pw_source_set("pico_stdlib") {
  public_configs = [ "${PICO_ROOT}/gn:disable_warnings" ]
  public_deps = [ ":headers" ]

  # Ensure the pico stdlib implementation is linked in.
  deps = [ "${PICO_ROOT}/src/rp2_common/pico_stdlib" ]
}