# Copyright 2019 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_malloc/backend.gni")
import("$dir_pw_toolchain/generate_toolchain.gni")
import("target_toolchains.gni")

generate_toolchains("target_toolchains") {
  toolchains = pw_target_toolchain_stm32f429i_disc1_list
}

config("pw_malloc_active") {
  if (pw_malloc_BACKEND != "") {
    defines = [ "PW_MALLOC_ACTIVE=1" ]
  }
}

if (current_toolchain != default_toolchain) {
  pw_source_set("pre_init") {
    configs = [ ":pw_malloc_active" ]
    public_deps = [
      "$dir_pw_boot_armv7m",
      "$dir_pw_sys_io_baremetal_stm32f429",
    ]
    deps = [
      "$dir_pw_malloc",
      "$dir_pw_preprocessor",
    ]
    sources = [
      "boot.cc",
      "vector_table.c",
    ]
  }

  pw_source_set("system_rpc_server") {
    deps = [
      "$dir_pw_hdlc:pw_rpc",
      "$dir_pw_hdlc:rpc_channel_output",
      "$dir_pw_rpc/system_server:facade",
      "$dir_pw_stream:sys_io_stream",
      dir_pw_log,
    ]
    sources = [ "system_rpc_server.cc" ]
  }
}

pw_doc_group("target_docs") {
  sources = [ "target_docs.rst" ]
}