# Copyright (c) 2020 Project CHIP Authors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build_overrides/chip.gni")
import("${chip_root}/src/platform/device.gni")
import("${chip_root}/src/platform/python.gni")

config("config") {
  # TODO: this should be a dependency on src/controller/data_model however this is circular:
  #    zzz_generated/controller-clusters depend on src/controller
  #    src/controller neeeds zzz_generated/controller-cluster for includes
  include_dirs = [ "${chip_root}/zzz_generated/" ]
}

static_library("controller") {
  output_name = "libChipController"

  sources = [
    "CHIPCluster.cpp",
    "CHIPCluster.h",
  ]

  if (chip_controller) {
    sources += [
      "AbstractDnssdDiscoveryController.cpp",
      "CHIPCommissionableNodeController.cpp",
      "CHIPCommissionableNodeController.h",
      "CHIPDeviceController.cpp",
      "CHIPDeviceController.h",
      "CHIPDeviceControllerFactory.cpp",
      "CHIPDeviceControllerFactory.h",
      "CommissioneeDeviceProxy.cpp",
      "CommissioneeDeviceProxy.h",
      "DeviceAddressUpdateDelegate.h",
      "DeviceDiscoveryDelegate.h",
      "EmptyDataModelHandler.cpp",
      "ExampleOperationalCredentialsIssuer.cpp",
      "ExampleOperationalCredentialsIssuer.h",
      "SetUpCodePairer.cpp",
      "SetUpCodePairer.h",
    ]
  }

  cflags = [ "-Wconversion" ]

  public_deps = [
    "${chip_root}/src/app",
    "${chip_root}/src/app/util:device_callbacks_manager",
    "${chip_root}/src/lib/core",
    "${chip_root}/src/lib/dnssd",
    "${chip_root}/src/lib/support",
    "${chip_root}/src/messaging",
    "${chip_root}/src/platform",
    "${chip_root}/src/protocols",
    "${chip_root}/src/setup_payload",
    "${chip_root}/src/transport",
  ]

  public_configs = [ ":config" ]

  defines = []
}