targets/stm32f730r8tx_arduino/arduino_executable.gni

# Copyright 2023 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/exec.gni")
import("$dir_pw_malloc/backend.gni")

template("arduino_executable") {
  _bin_name = "${target_name}.bin"
  _elf_name = "${target_name}.elf"

  # Compile the elf
  executable(_elf_name) {
    forward_variables_from(invoker, "*")
    if (!defined(deps)) {
      deps = []
    }
    deps += [ "$dir_pw_arduino_build:arduino_main_wrapper" ]
  }

  # objcopy a bin file for dfu-util flashing
  pw_exec(target_name) {
    _bin_out_path = "${target_out_dir}/${_bin_name}"
    deps = [ ":${_elf_name}" ]
    program = "arm-none-eabi-objcopy"
    args = [
      "-O",
      "binary",
      "<TARGET_FILE(:${_elf_name})>",
      rebase_path(_bin_out_path, root_build_dir),
    ]
    outputs = [ _bin_out_path ]
  }
}