pw_i2c/BUILD.gn

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_chrono/backend.gni")
import("$dir_pw_protobuf_compiler/proto.gni")
import("$dir_pw_unit_test/test.gni")
import("backend.gni")

config("public_include_path") {
  include_dirs = [ "public" ]
}

pw_source_set("address") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/address.h" ]
  public_deps = [ "$dir_pw_assert" ]
  sources = [ "address.cc" ]
}

pw_source_set("message") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/message.h" ]
  public_deps = [
    ":address",
    "$dir_pw_assert",
    "$dir_pw_bytes",
    "$dir_pw_status",
  ]
}

pw_source_set("initiator") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/initiator.h" ]
  public_deps = [
    ":address",
    ":message",
    "$dir_pw_bytes",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_containers:vector",
    "$dir_pw_status",
  ]
  sources = [ "initiator.cc" ]
}

pw_source_set("responder") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/responder.h" ]
  public_deps = [
    ":address",
    "$dir_pw_bytes",
    "$dir_pw_result",
    "$dir_pw_status",
  ]
}

pw_source_set("responder_test_interface") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/responder_test_interface.h" ]
  public_deps = [
    ":address",
    ":responder",
    "$dir_pw_bytes",
    "$dir_pw_function",
    "$dir_pw_result",
    "$dir_pw_status",
    "$dir_pw_unit_test",
  ]
}

if (pw_i2c_RESPONDER_TEST_BACKEND != "") {
  pw_test("responder_test") {
    sources = [ "responder_test.cc" ]
    deps = [
      ":responder_test_interface",
      "$dir_pw_unit_test",
      pw_i2c_RESPONDER_TEST_BACKEND,
    ]
  }
}

pw_source_set("device") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/device.h" ]
  public_deps = [
    ":address",
    ":initiator",
    "$dir_pw_bytes",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_status",
    dir_pw_span,
  ]
}

pw_source_set("register_device") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/register_device.h" ]
  public_deps = [
    ":address",
    ":device",
    ":initiator",
    "$dir_pw_bytes",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_result",
    "$dir_pw_status",
  ]
  sources = [ "register_device.cc" ]
  deps = [ "$dir_pw_assert" ]
}

pw_proto_library("protos") {
  sources = [ "i2c.proto" ]
  inputs = [ "i2c.pwpb_options" ]
  prefix = "pw_i2c"
}

pw_source_set("i2c_service") {
  public = [ "public/pw_i2c/i2c_service.h" ]
  sources = [ "i2c_service.cc" ]
  public_deps = [
    ":protos.pwpb_rpc",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_i2c:initiator",
  ]
  deps = [
    "$dir_pw_containers:vector",
    "$dir_pw_i2c:address",
    "$dir_pw_status",
  ]
}

pw_source_set("mock") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/initiator_mock.h" ]
  sources = [ "initiator_mock.cc" ]
  public_deps = [
    ":initiator",
    "$dir_pw_bytes",
    "$dir_pw_containers",
    "$dir_pw_containers:to_array",
  ]
  deps = [
    "$dir_pw_assert",
    "$dir_pw_unit_test",
  ]
}

pw_source_set("message_mock") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_i2c/initiator_message_mock.h" ]
  sources = [ "initiator_message_mock.cc" ]
  public_deps = [
    ":initiator",
    "$dir_pw_bytes",
    "$dir_pw_containers",
    "$dir_pw_containers:algorithm",
    "$dir_pw_containers:to_array",
  ]
  deps = [
    "$dir_pw_assert",
    "$dir_pw_unit_test",
  ]
}

pw_source_set("gmock") {
  public_configs = [ ":public_include_path" ]
  public_deps = [
    ":initiator",
    "$pw_external_googletest",
  ]
  public = [ "public/pw_i2c/initiator_gmock.h" ]
}

# TODO: add mock_test here once chrono backend is supported for stm32f429i-disc1
pw_test_group("tests") {
  tests = [
    ":address_test",
    ":device_test",
    ":device_message_test",
    ":initiator_mock_test",
    ":initiator_message_mock_test",
    ":initiator_test",
    ":message_test",
    ":register_device_test",
    ":i2c_service_test",
    ":i2c_message_service_test",
  ]
  if (pw_i2c_RESPONDER_TEST_BACKEND != "") {
    tests += [ ":responder_test" ]
  }
}

pw_test("address_test") {
  sources = [ "address_test.cc" ]
  deps = [ ":address" ]

  # Disable deprecation warning for Address() constructor.
  cflags = [ "-Wno-deprecated-declarations" ]
}

pw_test("message_test") {
  sources = [ "message_test.cc" ]
  deps = [
    ":address",
    ":message",
  ]
}

pw_test("initiator_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "initiator_test.cc" ]
  deps = [
    ":address",
    ":initiator",
    ":message",
    "$dir_pw_chrono:system_clock",
  ]
}

pw_test("device_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "device_test.cc" ]
  deps = [
    ":device",
    ":mock",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_containers",
  ]
}

pw_test("device_message_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "device_message_test.cc" ]
  deps = [
    ":device",
    ":message_mock",
    "$dir_pw_bytes",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_containers:algorithm",
  ]
}

pw_test("register_device_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "register_device_test.cc" ]
  deps = [
    ":register_device",
    "$dir_pw_assert",
  ]

  # TODO: https://pwbug.dev/325509758 - Doesn't work on the Pico yet; hangs
  # indefinitely.
  if (pw_build_EXECUTABLE_TARGET_TYPE == "pico_executable") {
    enable_if = false
  }
}

pw_test("initiator_mock_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "initiator_mock_test.cc" ]
  deps = [
    ":mock",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_containers",
  ]
}

pw_test("initiator_message_mock_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "initiator_message_mock_test.cc" ]
  deps = [
    ":address",
    ":message_mock",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_containers:to_array",
    dir_pw_span,
  ]
}

pw_test("i2c_service_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "i2c_service_test.cc" ]
  deps = [
    ":i2c_service",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_containers:vector",
    "$dir_pw_i2c:mock",
    "$dir_pw_rpc/pwpb:test_method_context",
    "$dir_pw_status",
  ]

  # TODO: https://pwbug.dev/325509758 - Doesn't work on the Pico yet; hangs
  # indefinitely.
  if (pw_build_EXECUTABLE_TARGET_TYPE == "pico_executable") {
    enable_if = false
  }
}

pw_test("i2c_message_service_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "i2c_message_service_test.cc" ]
  deps = [
    ":address",
    ":i2c_service",
    ":initiator",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_containers:vector",
    "$dir_pw_i2c:message_mock",
    "$dir_pw_rpc/pwpb:test_method_context",
    "$dir_pw_status",
  ]

  # TODO: https://pwbug.dev/325509758 - Doesn't work on the Pico yet; hangs
  # indefinitely.
  if (pw_build_EXECUTABLE_TARGET_TYPE == "pico_executable") {
    enable_if = false
  }
}