pw_interrupt/BUILD.bazel

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

load("@bazel_skylib//lib:selects.bzl", "selects")
load("@rules_cc//cc:cc_library.bzl", "cc_library")
load("@sphinxdocs//sphinxdocs:sphinx_docs_library.bzl", "sphinx_docs_library")
load("//pw_build:compatibility.bzl", "host_backend_alias", "incompatible_with_mcu")
load("//pw_build:pw_facade.bzl", "pw_facade")

package(default_visibility = ["//visibility:public"])

licenses(["notice"])

constraint_setting(
    name = "backend_constraint_setting",
)

pw_facade(
    name = "context",
    hdrs = [
        "public/pw_interrupt/context.h",
    ],
    backend = ":backend",
    strip_include_prefix = "public",
)

label_flag(
    name = "backend",
    build_setting_default = ":backend_multiplexer",
)

cc_library(
    name = "fake_context",
    srcs = ["fake_context.cc"],
    hdrs = [
        "public/pw_interrupt/context.h",
        "public/pw_interrupt/fake_context.h",
    ],
    strip_include_prefix = "public",
    deps = [
        ":context.facade",
        "//pw_function",
    ],
)

host_backend_alias(
    name = "unspecified_backend_context",
    backend = ":fake_context",
)

alias(
    name = "backend_multiplexer",
    actual = selects.with_or({
        (
            "//pw_interrupt_cortex_m:backend",
            "//pw_interrupt_cortex_m:compatible",
        ): "//pw_interrupt_cortex_m:context",
        (
            "//pw_interrupt_freertos:backend",
            "//pw_interrupt_freertos:compatible",
        ): "//pw_interrupt_freertos:context",
        "//conditions:default": ":unspecified_backend_context",
    }),
    visibility = ["//targets:__pkg__"],
)

filegroup(
    name = "doxygen",
    srcs = [
        "public/pw_interrupt/context.h",
        "public/pw_interrupt/fake_context.h",
    ],
)

sphinx_docs_library(
    name = "docs",
    srcs = [
        "backends.rst",
        "docs.rst",
        "fake_backend.rst",
    ],
    prefix = "pw_interrupt/",
    target_compatible_with = incompatible_with_mcu(),
)