pw_clock_tree/BUILD.gn

# Copyright 2024 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_thread/backend.gni")
import("$dir_pw_unit_test/test.gni")

config("default_config") {
  include_dirs = [ "public" ]
}

pw_source_set("pw_clock_tree") {
  public_configs = [ ":default_config" ]
  public = [
    "public/pw_clock_tree/clock_tree.h",
    "public/pw_clock_tree/internal/deferred_init.h",
  ]
  public_deps = [
    "$dir_pw_assert",
    "$dir_pw_status",
    "$dir_pw_sync:interrupt_spin_lock",
    "$dir_pw_sync:mutex",
  ]
}

pw_source_set("external_source") {
  public_configs = [ ":default_config" ]
  public = [ "public/pw_clock_tree/external_source.h" ]
  public_deps = [
    ":pw_clock_tree",
    "$dir_pw_digital_io",
    "$dir_pw_thread:sleep",
  ]
}

pw_test("clock_tree_test") {
  enable_if = pw_thread_THREAD_BACKEND != ""
  sources = [ "clock_tree_test.cc" ]
  deps = [
    ":external_source",
    ":pw_clock_tree",
  ]
  public_deps = [ "$dir_pw_preprocessor" ]
}

pw_test("dependency_test") {
  sources = [ "dependency_test.cc" ]
  deps = [ ":pw_clock_tree" ]
}

pw_test("dependency_nc_test") {
  sources = [ "dependency_nc_test.cc" ]
  deps = [ ":pw_clock_tree" ]
  negative_compilation_tests = true
}

pw_test("clock_tree_examples") {
  sources = [ "examples.cc" ]
  deps = [ ":pw_clock_tree" ]
}

pw_test_group("tests") {
  tests = [
    ":clock_tree_test",
    ":dependency_test",
    ":dependency_nc_test",
    ":clock_tree_examples",
  ]
}