pw_kernel/target/BUILD.bazel

# Copyright 2025 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

load("@bazel_skylib//lib:selects.bzl", "selects")
load("@rules_rust//rust:defs.bzl", "rust_library")
load("//pw_build/constraints/arm:lists.bzl", "ALL_CORTEX_M_CPUS")
load("//pw_build/constraints/riscv:lists.bzl", "ALL_RISCV_CPUS")

package(default_visibility = ["//visibility:public"])

rust_library(
    name = "target_common",
    srcs = ["target_common.rs"],
    edition = "2024",
    tags = ["kernel"],
    deps = [
        "//pw_assert/rust:pw_assert",
        "//pw_log/rust:pw_log",
    ],
)

label_flag(
    name = "system_config_file",
    build_setting_default = ":no_system_config_file",
    tags = ["kernel"],
)

filegroup(
    name = "no_system_config_file",
    tags = ["kernel"],
    target_compatible_with = ["@platforms//:incompatible"],
)

config_setting(
    name = "system_config_not_set",
    flag_values = {
        ":system_config_file": ":no_system_config_file",
    },
)

constraint_setting(
    name = "target",
    default_constraint_value = "none",
)

constraint_value(
    name = "none",
    constraint_setting = ":target",
)

label_flag(
    name = "target_arch",
    build_setting_default = ":default_target_arch",
)

alias(
    name = "default_target_arch",
    actual = selects.with_or({
        ALL_CORTEX_M_CPUS: "//pw_kernel/arch/arm_cortex_m:arch_arm_cortex_m",
        ALL_RISCV_CPUS: "//pw_kernel/arch/riscv:arch_riscv",
        "//conditions:default": "@platforms//:incompatible",
    }),
)