libraries/kotlin.test/junit5/build.gradle

description = 'Kotlin Test JUnit 5'

apply plugin: 'kotlin-platform-jvm'

def includeJava9 = BuildPropertiesExtKt.getIncludeJava9(project.kotlinBuildProperties)

sourceSets {
    if (includeJava9) {
        java9
    }
}

project.ext["jpsLibraryPath"] = rootProject.distLibDir

dependencies {
    expectedBy project(':kotlin-test:kotlin-test-annotations-common')
    api project(':kotlin-test:kotlin-test-jvm')

    api("org.junit.jupiter:junit-jupiter-api:5.0.0")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.2.0")
}

jar {
    LibrariesCommon.manifestAttributes(project, manifest, 'Test', true)
    if (includeJava9) {
        from sourceSets.java9.output
    }
}

RepoArtifacts.sourcesJar(project)
RepoArtifacts.javadocJar(project)

compileKotlin {
    kotlinOptions.freeCompilerArgs = [
        "-Xallow-kotlin-package",
    ]
    kotlinOptions.moduleName = project.name
}

compileTestKotlin {
    kotlinOptions.freeCompilerArgs = [
        "-Xallow-kotlin-package",
    ]
}

LibrariesCommon.configureFrontendIr(project)

if (includeJava9) {
    LibrariesCommon.configureJava9Compilation(project, 'kotlin.test.junit5')
}

test {
    useJUnitPlatform()
}