libraries/tools/kotlin-noarg/build.gradle

apply plugin: 'kotlin'
apply plugin: 'jps-compatible'

configureGradlePluginPublishing(project)

compileJava {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
    options.fork = false
}

pill {
    variant = 'FULL'
}

dependencies {
    compile project(':kotlin-gradle-plugin-api')
    compile project(':kotlin-gradle-plugin-model')

    compile kotlinStdlib()
    compileOnly project(':compiler')
    compileOnly project(':kotlin-noarg-compiler-plugin')

    compileOnly gradleApi()

    testCompile gradleApi()
    testCompile "junit:junit:4.12"

    embedded(project(":kotlin-noarg-compiler-plugin")) { transitive = false }
}

tasks.withType(project.compileKotlin.class) {
    kotlinOptions.languageVersion = "1.3"
    kotlinOptions.apiVersion = "1.3"
    kotlinOptions.freeCompilerArgs += [
            "-Xskip-prerelease-check", "-Xskip-runtime-version-check", "-Xsuppress-version-warnings"
    ]
}

jar {
    manifestAttributes(manifest, project)
}

ArtifactsKt.noDefaultJar(project)
ArtifactsKt.runtimeJar(project, EmbeddableKt.rewriteDefaultJarDepsToShadedCompiler(project, {}), {})
configureSourcesJar()
configureJavadocJar()

pluginBundle {
    plugins {
        kotlinNoargPlugin {
            id = 'org.jetbrains.kotlin.plugin.noarg'
            description = displayName = 'Kotlin No Arg compiler plugin'
        }
        kotlinJpaPlugin {
            id = 'org.jetbrains.kotlin.plugin.jpa'
            description = displayName = 'Kotlin JPA compiler plugin'
        }
    }
}

configurePluginMarkers(project)

test.executable = "${JDK_18}/bin/java"