build/toolchain/tizen/tizen_toolchain.gni

# Copyright (c) 2021 Project CHIP Authors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build_overrides/build.gni")

import("${build_root}/config/tizen/config.gni")
import("${build_root}/toolchain/gcc_toolchain.gni")

template("tizen_toolchain") {
  _invoker_toolchain_args = invoker.toolchain_args

  _tizen_toolchain_args = {
    current_os = "tizen"
    is_clang = false

    forward_variables_from(_invoker_toolchain_args, "*")
  }

  if (_invoker_toolchain_args.current_cpu == "arm") {
    _tizen_toolchain_prefix = "${tizen_sdk_root}/tools/arm-linux-gnueabi-gcc-14.2/bin/arm-linux-gnueabi-"
  } else if (_invoker_toolchain_args.current_cpu == "arm64") {
    _tizen_toolchain_prefix = "${tizen_sdk_root}/tools/aarch64-linux-gnu-gcc-14.2/bin/aarch64-linux-gnu-"
  } else {
    assert(false, "CPU architecture is not supported.")
  }

  gcc_toolchain(target_name) {
    toolchain_args = _tizen_toolchain_args
    ar = _tizen_toolchain_prefix + "ar"
    cc = _tizen_toolchain_prefix + "gcc"
    cxx = _tizen_toolchain_prefix + "g++"
  }
}