src/platform/realtek/freertos/BUILD.gn

# Copyright (c) 2021-2026 Project CHIP Authors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build_overrides/chip.gni")

import("//src/platform/device.gni")

assert(chip_device_platform == "realtek_bee")

declare_args() {
  chip_use_cg_secure_dac_vendor = false
}

static_library("freertos") {
  sources = [
    "//src/platform/SingletonConfigurationManager.cpp",
    "BLEManagerImpl.cpp",
    "BLEManagerImpl.h",
    "BlePlatformConfig.h",
    "CHIPDevicePlatformConfig.h",
    "CHIPDevicePlatformEvent.h",
    "CHIPPlatformConfig.h",
    "ConfigurationManagerImpl.cpp",
    "ConfigurationManagerImpl.h",
    "ConnectivityManagerImpl.cpp",
    "ConnectivityManagerImpl.h",
    "DiagnosticDataProviderImpl.cpp",
    "DiagnosticDataProviderImpl.h",
    "FactoryDataDecoder.cpp",
    "FactoryDataDecoder.h",
    "FactoryDataProvider.cpp",
    "FactoryDataProvider.h",
    "InetPlatformConfig.h",
    "KeyValueStoreManagerImpl.cpp",
    "KeyValueStoreManagerImpl.h",
    "OTAImageProcessorImpl.cpp",
    "OTAImageProcessorImpl.h",
    "PlatformManagerImpl.cpp",
    "PlatformManagerImpl.h",
    "RTKConfig.cpp",
    "RTKConfig.h",
    "SystemPlatformConfig.h",
    "SystemTimeSupport.cpp",
    "SystemTimeSupport.h",
  ]

  deps = [
    "${chip_root}/src/app:app_config",
    "${chip_root}/src/app/clusters/ota-requestor:interface",
    "${chip_root}/src/app/common:ids",
    "${chip_root}/src/lib/dnssd:platform_header",
    "${chip_root}/src/platform/logging:headers",
    "${chip_root}/src/setup_payload",
  ]

  public = [ "${chip_root}/src/credentials/DeviceAttestationCredsProvider.h" ]

  public_deps = [ "${chip_root}/src/platform:platform_base" ]

  public_configs = []

  if (chip_enable_thread) {
    sources += [
      "//src/platform/OpenThread/GenericNetworkCommissioningThreadDriver.cpp",
      "//src/platform/OpenThread/GenericNetworkCommissioningThreadDriver.h",
      "//src/platform/OpenThread/OpenThreadDnssdImpl.cpp",
      "//src/platform/OpenThread/OpenThreadDnssdImpl.h",
      "//src/platform/OpenThread/OpenThreadUtils.cpp",
      "ThreadStackManagerImpl.cpp",
      "ThreadStackManagerImpl.h",
    ]

    if (chip_mdns == "platform") {
      sources += [ "//src/platform/OpenThread/DnssdImpl.cpp" ]
      deps += [ "//src/lib/dnssd:platform_header" ]
    }
  }

  sources += [
    "RTK/RTKDACVendorProvider.cpp",
    "RTK/RTKDACVendorProvider.h",
  ]

  if (chip_use_cg_secure_dac_vendor) {
    sources += [
      "CG/CGSecureDACVendorProvider.cpp",
      "CG/CGSecureDACVendorProvider.h",
    ]
    defines = [ "CONFIG_USE_CG_SECURE_DAC_VENDOR=1" ]
  }
}

source_set("logging") {
  deps = [
    "${chip_root}/src/platform:platform_base",
    "${chip_root}/src/platform/logging:headers",
  ]
  sources = [ "Logging.cpp" ]
}