third_party/openthread/BUILD.gn

import("//build_overrides/chip.gni")
import("//build_overrides/openthread.gni")

import("${chip_root}/src/platform/device.gni")

declare_args() {
  # Use a different target, such as a prebuilt Thread library.
  chip_openthread_target = ""
}

group("openthread-platform") {
  if (chip_openthread_target != "") {
    public_deps = [ chip_openthread_target ]
  } else {
    public_deps = [
      "${chip_root}/third_party/openthread/platforms:libopenthread-platform",
      "${chip_root}/third_party/openthread/platforms:libopenthread-platform-utils",
    ]
  }
}

group("openthread") {
  if (chip_openthread_target != "") {
    public_deps = [ chip_openthread_target ]
  } else {
    if (chip_openthread_ftd) {
      public_deps = [ "${openthread_root}:libopenthread-ftd" ]
    } else {
      public_deps = [ "${openthread_root}:libopenthread-mtd" ]
    }
  }
}

group("openthread_cli") {
  if (chip_openthread_target == "") {
    if (chip_openthread_ftd) {
      public_deps = [ "${openthread_root}:libopenthread-cli-ftd" ]
    } else {
      public_deps = [ "${openthread_root}:libopenthread-cli-mtd" ]
    }
  }
}