examples/platform/qpg/BUILD.gn

# Copyright (c) 2021 Project CHIP Authors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build_overrides/chip.gni")
import("//build_overrides/qpg_sdk.gni")

import("${qpg_sdk_build_root}/qpg_sdk.gni")

# declares chip_build_libshell = false
import("${chip_root}/src/lib/lib.gni")
config("chip_examples_project_config") {
  include_dirs = [ "project_include" ]
}

source_set("openthread_core_config_qpg_chip_examples") {
  sources = [ "project_include/OpenThreadConfig.h" ]

  public_deps = [
    "${chip_root}/third_party/openthread/platforms/qpg:openthread_core_config_qpg",
    "${qpg_sdk_build_root}:qpg_sdk",
  ]

  public_configs = [ ":chip_examples_project_config" ]
}

source_set("qpg-matter-shell") {
  if (chip_build_libshell) {
    defines = [
      "OPENTHREAD_CONFIG_CLI_TRANSPORT=OT_CLI_TRANSPORT_CONSOLE",
      "ENABLE_CHIP_SHELL",
      "CHIP_DEVICE_CONFIG_THREAD_ENABLE_CLI=1",
    ]

    sources = [
      "shell_common/shell.cpp",
      "uart.c",
    ]

    include_dirs = [ "." ]

    public_deps = [
      "${chip_root}/examples/shell/shell_common:shell_common",
      "${chip_root}/src/lib/shell:shell",
      "${chip_root}/src/lib/shell:shell_core",
    ]
  }
}