examples/shell/shell_common/BUILD.gn

# Copyright (c) 2020-2026 Project CHIP Authors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build_overrides/chip.gni")
import("${chip_root}/config/recommended.gni")
import("${chip_root}/src/platform/device.gni")

declare_args() {
  chip_shell_cmd_server = matter_enable_recommended &&
                          (current_os == "linux" || current_os == "mac")
}

# When true, shell_common links the all-clusters-app data model and mode-cluster
# glue (for standalone chip-shell on Linux/macOS). Embedded apps (Bouffalolab,
# Chef, etc.) must set this false so they only use their own chip_data_model
# target and chip_app_data_model_target visibility for required-privileges.
declare_args() {
  shell_use_all_clusters_data_model = chip_shell_cmd_server
}

_shell_enable_cmd_server =
    chip_shell_cmd_server && shell_use_all_clusters_data_model

config("shell_common_config") {
  include_dirs = [
    ".",
    "include",
    "${chip_root}/src/lib/shell",
  ]

  defines = [
    "ENABLE_CHIP_SHELL",
    "OPENTHREAD_CONFIG_CLI_TRANSPORT=OT_CLI_TRANSPORT_CONSOLE",
    "CHIP_SHELL_ENABLE_CMD_SERVER=${_shell_enable_cmd_server}",
  ]
}

static_library("shell_common") {
  sources = [
    "cmd_misc.cpp",
    "cmd_otcli.cpp",
    "globals.cpp",
  ]

  public_deps = [
    "${chip_root}/src/lib/shell",
    "${chip_root}/src/lib/support",
    "${chip_root}/src/platform",
    "${chip_root}/src/protocols",
  ]

  if (chip_enable_thread &&
      (current_os == "freertos" || current_os == "zephyr")) {
    public_deps += [
      "${chip_root}/third_party/openthread:openthread",
      "${chip_root}/third_party/openthread:openthread_cli",
    ]
  }

  if (_shell_enable_cmd_server) {
    sources += [ "cmd_server.cpp" ]

    import("${chip_root}/src/app/chip_data_model.gni")

    sources += [
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/bridged-actions-stub.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/dishwasher-mode.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/laundry-washer-mode.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/microwave-oven-mode.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/operational-state-delegate-impl.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/oven-modes.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/oven-operational-state-delegate.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/rvc-modes.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/rvc-operational-state-delegate-impl.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/smco-stub.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/soil-measurement-stub.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/static-supported-modes-manager.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/static-supported-temperature-levels.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/tcc-mode.cpp",
      "${chip_root}/examples/all-clusters-app/all-clusters-common/src/test-hidden-manufacturer-specific-stub.cpp",
    ]

    include_dirs =
        [ "${chip_root}/examples/all-clusters-app/all-clusters-common/include" ]

    public_deps += [
      "${chip_root}/examples/all-clusters-app/all-clusters-common",
      "${chip_root}/src/app/clusters/boolean-state-server",
    ]

    deps = [
      "${chip_root}/src/app:attribute-persistence",
      "${chip_root}/src/lib/support:arg_parser",
    ]
  }

  public_configs = [ ":shell_common_config" ]

  cflags = [ "-Wconversion" ]
}