pw_display_driver_ili9341/BUILD.gn

# Copyright 2022 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_third_party/stm32cube/stm32cube.gni")

declare_args() {
  # The ILI9341 MADCTL register value to set during initialization.
  # The default is portrait adressing in BGR order.
  pw_display_driver_ili9341_MADCTL = "0"
}

config("default_config") {
  include_dirs = [ "public" ]
}

config("private_config") {
  cflags = [ "-DILI9341_MADCTL=" + pw_display_driver_ili9341_MADCTL ]
}

pw_source_set("pw_display_driver_ili9341") {
  public_configs = [ ":default_config" ]
  configs = [ ":private_config" ]
  public = [ "public/pw_display_driver_ili9341/display_driver.h" ]
  deps = [
    "$dir_pw_log",
    "$dir_pw_spin_delay",
  ]
  public_deps = [
    "$dir_pw_digital_io",
    "$dir_pw_display_driver:display_driver",
    "$dir_pw_framebuffer_pool",
    "$dir_pw_pixel_pusher:pixel_pusher",
    "$dir_pw_spi:device",
  ]
  sources = [ "display_driver.cc" ]
  remove_configs = [ "$dir_pw_build:strict_warnings" ]
}