blob: 157472b8bf5c31e8865aaccfa8624cae4f1f2751 [file] [log] [blame]
# Copyright 2019 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
# https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.
import("//build_overrides/pigweed.gni")
import("$dir_pw_build/module_config.gni")
import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_unit_test/test.gni")
declare_args() {
# The build target that overrides the default configuration options for this
# module. This should point to a source set that provides defines through a
# public config (which may -include a file or add defines directly).
pw_status_CONFIG = pw_build_DEFAULT_MODULE_CONFIG
}
config("public_include_path") {
include_dirs = [ "public" ]
visibility = [ ":*" ]
}
pw_source_set("pw_status") {
public_configs = [ ":public_include_path" ]
public_deps = [ pw_status_CONFIG ]
public = [
"public/pw_status/status.h",
"public/pw_status/status_with_size.h",
"public/pw_status/try.h",
]
sources = [
"public/pw_status/internal/config.h",
"status.cc",
]
}
config("check_if_used_config") {
defines = [ "PW_STATUS_CFG_CHECK_IF_USED=1" ]
visibility = [ ":*" ]
}
# Use this for pw_status_CONFIG to require pw::Status objects to be used.
pw_source_set("check_if_used") {
public_configs = [ ":check_if_used_config" ]
}
pw_test_group("tests") {
tests = [
":status_test",
":status_with_size_test",
":try_test",
]
}
pw_test("status_test") {
deps = [ ":pw_status" ]
sources = [
"status_test.cc",
"status_test_c.c",
]
}
pw_test("status_with_size_test") {
deps = [ ":pw_status" ]
sources = [ "status_with_size_test.cc" ]
}
pw_test("try_test") {
deps = [ ":pw_status" ]
sources = [ "try_test.cc" ]
}
pw_doc_group("docs") {
sources = [ "docs.rst" ]
}