pw_fuzzer/examples/fuzztest/BUILD.gn

# Copyright 2023 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_unit_test/test.gni")

config("includes") {
  visibility = [ ":*" ]
  include_dirs = [ "." ]
}

pw_source_set("metrics_lib") {
  visibility = [ ":*" ]
  public = [ "metrics.h" ]
  sources = [ "metrics.cc" ]
  public_configs = [ ":includes" ]
  public_deps = [
    dir_pw_bytes,
    dir_pw_containers,
    dir_pw_status,
    dir_pw_string,
  ]
  deps = [ "$dir_pw_assert:check" ]
}

pw_test("metrics_unittest") {
  sources = [ "metrics_unittest.cc" ]
  deps = [ ":metrics_lib" ]
}

# DOCSTAG: [pwfuzzer_examples_fuzztest-gn]
pw_test("metrics_fuzztest") {
  sources = [ "metrics_fuzztest.cc" ]
  deps = [
    ":metrics_lib",
    "$dir_pw_fuzzer:fuzztest",  # <- Added!
  ]

  # TODO: b/283156908 - Re-enable with a fixed seed.
  enable_if = false
}

# DOCSTAG: [pwfuzzer_examples_fuzztest-gn]
pw_test_group("tests") {
  tests = [
    ":metrics_unittest",
    ":metrics_fuzztest",
  ]
}