pw_i2c_rp2040/BUILD.gn

# Copyright 2024 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.
import("//build_overrides/pi_pico.gni")
import("//build_overrides/pigweed.gni")
import("$dir_pw_build/target_types.gni")
import("$dir_pw_chrono/backend.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_unit_test/test.gni")

config("default_config") {
  include_dirs = [ "public" ]
}

pw_source_set("pw_i2c_rp2040") {
  public_configs = [ ":default_config" ]
  public = [ "public/pw_i2c_rp2040/initiator.h" ]
  public_deps = [
    "$PICO_ROOT/src/rp2_common/hardware_gpio",
    "$PICO_ROOT/src/rp2_common/hardware_i2c",
    "$dir_pw_i2c:initiator",
    "$dir_pw_status",
    "$dir_pw_sync:lock_annotations",
    "$dir_pw_sync:mutex",
  ]
  deps = [
    "$PICO_ROOT/src/common/pico_base",
    "$PICO_ROOT/src/common/pico_stdlib",
    "$dir_pw_chrono:system_clock",
    "$dir_pw_digital_io",
    "$dir_pw_log",
  ]
  sources = [ "initiator.cc" ]
  remove_configs = [ "$dir_pw_build:strict_warnings" ]
}

pw_test("initiator_test") {
  deps = [ ":pw_i2c_rp2040" ]
  sources = [ "initiator_test.cc" ]
  enable_if =
      pw_chrono_SYSTEM_CLOCK_BACKEND == "$dir_pw_chrono_rp2040:system_clock"
}

pw_doc_group("docs") {
  sources = [ "docs.rst" ]
}

pw_test_group("tests") {
  tests = [ ":initiator_test" ]
}