pw_log/BUILD.gn

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("$dir_pw_build/facade.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_unit_test/test.gni")

config("default_config") {
  include_dirs = [ "public" ]
}

pw_facade("pw_log") {
  backend = dir_pw_log_backend
  public_configs = [ ":default_config" ]
  public = [
    "public/pw_log/levels.h",
    "public/pw_log/log.h",
  ]
  public_deps = [
    dir_pw_preprocessor,
  ]
}

pw_test_group("tests") {
  tests = []
  if (dir_pw_log_backend != "") {
    tests += [ ":basic_log_test" ]
  }
}

if (dir_pw_log_backend != "") {
  pw_test("basic_log_test") {
    deps = [
      ":pw_log",
      dir_pw_log_backend,
    ]

    sources = [
      "basic_log_test.cc",
      "basic_log_test_plain_c.c",
    ]
  }
}

pw_doc_group("docs") {
  sources = [
    "docs.rst",
  ]
}