blob: f857b118d10dba1cf642df2655bd325ebdf7f563 [file] [log] [blame]
# Copyright 2021 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
# https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.
import("//build_overrides/pigweed.gni")
import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_unit_test/test.gni")
config("public_include_path") {
include_dirs = [ "public" ]
}
group("pw_spi") {
deps = [
":chip_selector",
":device",
":initiator",
]
if (host_os == "linux") {
deps += [ ":linux_spi" ]
}
}
pw_source_set("initiator") {
public_configs = [ ":public_include_path" ]
public = [ "public/pw_spi/initiator.h" ]
public_deps = [
"$dir_pw_assert",
"$dir_pw_bytes",
"$dir_pw_status",
]
}
pw_source_set("chip_selector") {
public_configs = [ ":public_include_path" ]
public = [ "public/pw_spi/chip_selector.h" ]
public_deps = [ "$dir_pw_status" ]
}
pw_source_set("device") {
public_configs = [ ":public_include_path" ]
public = [ "public/pw_spi/device.h" ]
public_deps = [
":chip_selector",
":initiator",
"$dir_pw_bytes",
"$dir_pw_status",
"$dir_pw_sync:borrow",
]
}
pw_source_set("mock") {
public_configs = [ ":public_include_path" ]
public = [
"public/pw_spi/chip_selector_mock.h",
"public/pw_spi/initiator_mock.h",
]
sources = [ "initiator_mock.cc" ]
public_deps = [
":chip_selector",
":initiator",
"$dir_pw_bytes",
"$dir_pw_containers:to_array",
]
deps = [
"$dir_pw_assert",
"$dir_pw_unit_test",
]
}
# Linux-specific spidev implementation.
pw_source_set("linux_spi") {
public_configs = [ ":public_include_path" ]
public = [ "public/pw_spi/linux_spi.h" ]
public_deps = [
":device",
"$dir_pw_bytes",
"$dir_pw_log",
"$dir_pw_status",
"$dir_pw_sync:borrow",
"$dir_pw_sync:mutex",
]
sources = [ "linux_spi.cc" ]
}
pw_test_group("tests") {
tests = [
":spi_test",
":initiator_mock_test",
]
}
pw_test("spi_test") {
sources = [ "spi_test.cc" ]
deps = [
":device",
"$dir_pw_sync:mutex",
]
}
pw_test("initiator_mock_test") {
sources = [ "initiator_mock_test.cc" ]
deps = [ ":mock" ]
}
# Linux tests currently only work on a target with spidev support and a SPI endpoint
# mounted at /dev/spidev0.0
pw_test("linux_spi_test") {
sources = [ "linux_spi_test.cc" ]
deps = [
":device",
":linux_spi",
]
}
pw_doc_group("docs") {
sources = [ "docs.rst" ]
}