pw_sys_io_emcraft_sf2/BUILD.gn

# Copyright 2022 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/module_config.gni")
import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_third_party/smartfusion_mss/mss.gni")
import("$dir_pw_unit_test/test.gni")

declare_args() {
  # The build target that overrides the default configuration options for this
  # module. This should point to a source set that provides defines through a
  # public config (which may -include a file or add defines directly).
  pw_sys_io_emcraft_sf2_CONFIG = pw_build_DEFAULT_MODULE_CONFIG
}

config("public_includes") {
  include_dirs = [ "public" ]
}

pw_source_set("config") {
  public_deps = [ pw_sys_io_emcraft_sf2_CONFIG ]
  public = [ "pw_sys_io_emcraft_sf2_private/config.h" ]
  visibility = [ ":*" ]
}

pw_source_set("pw_sys_io_emcraft_sf2") {
  public_configs = [ ":public_includes" ]
  public_deps = [
    "$dir_pw_preprocessor",
    "$dir_pw_third_party/smartfusion_mss",
  ]
  if (dir_pw_third_party_smartfusion_mss != "") {
    public_deps += [ "$dir_pw_third_party/smartfusion_mss" ]
  }
  public = [ "public/pw_sys_io_emcraft_sf2/init.h" ]
  sources = [ "sys_io_emcraft_sf2.cc" ]
  deps = [
    ":config",
    "$dir_pw_status",
    "$dir_pw_sys_io:default_putget_bytes",
    "$dir_pw_sys_io:facade",
  ]
}

pw_doc_group("docs") {
  sources = [ "docs.rst" ]
}

pw_test_group("tests") {
}