| /* | |
| FreeRTOS V8.2.0rc1 - Copyright (C) 2014 Real Time Engineers Ltd. | |
| All rights reserved | |
| VISIT http://www.FreeRTOS.org TO ENSURE YOU ARE USING THE LATEST VERSION. | |
| This file is part of the FreeRTOS distribution. | |
| FreeRTOS is free software; you can redistribute it and/or modify it under | |
| the terms of the GNU General Public License (version 2) as published by the | |
| Free Software Foundation >>!AND MODIFIED BY!<< the FreeRTOS exception. | |
| >>! NOTE: The modification to the GPL is included to allow you to !<< | |
| >>! distribute a combined work that includes FreeRTOS without being !<< | |
| >>! obliged to provide the source code for proprietary components !<< | |
| >>! outside of the FreeRTOS kernel. !<< | |
| FreeRTOS is distributed in the hope that it will be useful, but WITHOUT ANY | |
| WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS | |
| FOR A PARTICULAR PURPOSE. Full license text is available on the following | |
| link: http://www.freertos.org/a00114.html | |
| 1 tab == 4 spaces! | |
| *************************************************************************** | |
| * * | |
| * Having a problem? Start by reading the FAQ "My application does * | |
| * not run, what could be wrong?". Have you defined configASSERT()? * | |
| * * | |
| * http://www.FreeRTOS.org/FAQHelp.html * | |
| * * | |
| *************************************************************************** | |
| *************************************************************************** | |
| * * | |
| * FreeRTOS provides completely free yet professionally developed, * | |
| * robust, strictly quality controlled, supported, and cross * | |
| * platform software that is more than just the market leader, it * | |
| * is the industry's de facto standard. * | |
| * * | |
| * Help yourself get started quickly while simultaneously helping * | |
| * to support the FreeRTOS project by purchasing a FreeRTOS * | |
| * tutorial book, reference manual, or both: * | |
| * http://www.FreeRTOS.org/Documentation * | |
| * * | |
| *************************************************************************** | |
| *************************************************************************** | |
| * * | |
| * Investing in training allows your team to be as productive as * | |
| * possible as early as possible, lowering your overall development * | |
| * cost, and enabling you to bring a more robust product to market * | |
| * earlier than would otherwise be possible. Richard Barry is both * | |
| * the architect and key author of FreeRTOS, and so also the world's * | |
| * leading authority on what is the world's most popular real time * | |
| * kernel for deeply embedded MCU designs. Obtaining your training * | |
| * from Richard ensures your team will gain directly from his in-depth * | |
| * product knowledge and years of usage experience. Contact Real Time * | |
| * Engineers Ltd to enquire about the FreeRTOS Masterclass, presented * | |
| * by Richard Barry: http://www.FreeRTOS.org/contact | |
| * * | |
| *************************************************************************** | |
| *************************************************************************** | |
| * * | |
| * You are receiving this top quality software for free. Please play * | |
| * fair and reciprocate by reporting any suspected issues and * | |
| * participating in the community forum: * | |
| * http://www.FreeRTOS.org/support * | |
| * * | |
| * Thank you! * | |
| * * | |
| *************************************************************************** | |
| http://www.FreeRTOS.org - Documentation, books, training, latest versions, | |
| license and Real Time Engineers Ltd. contact details. | |
| http://www.FreeRTOS.org/plus - A selection of FreeRTOS ecosystem products, | |
| including FreeRTOS+Trace - an indispensable productivity tool, a DOS | |
| compatible FAT file system, and our tiny thread aware UDP/IP stack. | |
| http://www.FreeRTOS.org/labs - Where new FreeRTOS products go to incubate. | |
| Come and try FreeRTOS+TCP, our new open source TCP/IP stack for FreeRTOS. | |
| http://www.OpenRTOS.com - Real Time Engineers ltd license FreeRTOS to High | |
| Integrity Systems ltd. to sell under the OpenRTOS brand. Low cost OpenRTOS | |
| licenses offer ticketed support, indemnification and commercial middleware. | |
| http://www.SafeRTOS.com - High Integrity Systems also provide a safety | |
| engineered and independently SIL3 certified version for use in safety and | |
| mission critical applications that require provable dependability. | |
| 1 tab == 4 spaces! | |
| */ | |
| #include "msp430.h" | |
| #include "FreeRTOSConfig.h" | |
| #include "data_model.h" | |
| IMPORT xTaskIncrementTick | |
| IMPORT vTaskSwitchContext | |
| IMPORT vPortSetupTimerInterrupt | |
| IMPORT pxCurrentTCB | |
| IMPORT usCriticalNesting | |
| EXPORT vPortTickISR | |
| EXPORT vPortYield | |
| EXPORT xPortStartScheduler | |
| portSAVE_CONTEXT macro | |
| /* Save the remaining registers. */ | |
| pushm_x #12, r15 | |
| mov.w &usCriticalNesting, r14 | |
| push_x r14 | |
| mov_x &pxCurrentTCB, r12 | |
| mov_x sp, 0( r12 ) | |
| endm | |
| /*-----------------------------------------------------------*/ | |
| portRESTORE_CONTEXT macro | |
| mov_x &pxCurrentTCB, r12 | |
| mov_x @r12, sp | |
| pop_x r15 | |
| mov.w r15, &usCriticalNesting | |
| popm_x #12, r15 | |
| pop.w sr | |
| reta | |
| endm | |
| /*-----------------------------------------------------------*/ | |
| /* | |
| * The RTOS tick ISR. | |
| * | |
| * If the cooperative scheduler is in use this simply increments the tick | |
| * count. | |
| * | |
| * If the preemptive scheduler is in use a context switch can also occur. | |
| */ | |
| RSEG CODE | |
| EVEN | |
| vPortTickISR: | |
| /* The sr is not saved in portSAVE_CONTEXT() because vPortYield() needs | |
| to save it manually before it gets modified (interrupts get disabled). | |
| Entering through this interrupt means the SR is already on the stack, but | |
| this keeps the stack frames identical. */ | |
| push.w sr | |
| portSAVE_CONTEXT | |
| calla #xTaskIncrementTick | |
| cmp.w #0x0, R12 | |
| jeq SkipContextSwitch | |
| calla #vTaskSwitchContext | |
| SkipContextSwitch: | |
| portRESTORE_CONTEXT | |
| /*-----------------------------------------------------------*/ | |
| /* | |
| * Manual context switch called by the portYIELD() macro. | |
| */ | |
| EVEN | |
| vPortYield: | |
| /* The sr needs saving before it is modified. */ | |
| push.w sr | |
| /* Now the SR is stacked we can disable interrupts. */ | |
| dint | |
| nop | |
| /* Save the context of the current task. */ | |
| portSAVE_CONTEXT | |
| /* Select the next task to run. */ | |
| calla #vTaskSwitchContext | |
| /* Restore the context of the new task. */ | |
| portRESTORE_CONTEXT | |
| /*-----------------------------------------------------------*/ | |
| /* | |
| * Start off the scheduler by initialising the RTOS tick timer, then restoring | |
| * the context of the first task. | |
| */ | |
| EVEN | |
| xPortStartScheduler: | |
| /* Setup the hardware to generate the tick. Interrupts are disabled | |
| when this function is called. */ | |
| calla #vPortSetupTimerInterrupt | |
| /* Restore the context of the first task that is going to run. */ | |
| portRESTORE_CONTEXT | |
| /*-----------------------------------------------------------*/ | |
| END | |