Track transitive neverlink jars in JavaInfo.

`JavaInfo` clears `transitive_runtime_jars` at `neverlink = True` boundaries, leaving downstream actions such as `one_version` duplicate class checking and ProGuard/R8 `-libraryjars` without access to the full class jars of `neverlink` dependencies unless a separate aspect traverses the dependency graph.

Add `_transitive_neverlink_jars` to `JavaInfo` to collect `transitive_runtime_jars` at `neverlink = True` boundaries and propagate them across `deps`, `runtime_deps`, and `exports`, as well as through `java_common.merge` and `to_implicit_exportable`.

The memory overhead scales with `neverlink` usage: when a target and its transitive dependencies do not use `neverlink`, `depset` construction skips empty transitive sets and returns the singleton empty `Depset` without allocating a new `NestedSet` node (only the reference slot in `JavaInfo`'s shared `StarlarkInfo` layout is populated). When a non-`neverlink` target has a single dependency branch with non-empty `_transitive_neverlink_jars`, `NestedSetBuilder` reuses that child `NestedSet` directly, so new `NestedSet` nodes are allocated only at `neverlink = True` targets or when merging multiple non-empty `_transitive_neverlink_jars` branches.

PiperOrigin-RevId: 1016498690
Change-Id: Ic05e96376751f3b1888c3d74b96c9a8e3df9aa29
diff --git a/java/private/java_info.bzl b/java/private/java_info.bzl
index e873ee1..dafe116 100644
--- a/java/private/java_info.bzl
+++ b/java/private/java_info.bzl
@@ -118,6 +118,7 @@
     full_compile_jars = []  # [depset[File]]
     _transitive_full_compile_time_jars = []  # [depset[File]]
     _compile_time_java_dependencies = []  # [depset[File]]
+    _transitive_neverlink_jars = []  # [depset[File]]
     add_exports = []  # [depset[str]]
     add_opens = []  # [depset[str]]
     _neverlink = False
@@ -136,6 +137,7 @@
         full_compile_jars.append(p.full_compile_jars)
         _transitive_full_compile_time_jars.append(p._transitive_full_compile_time_jars)
         _compile_time_java_dependencies.append(p._compile_time_java_dependencies)
+        _transitive_neverlink_jars.append(p._transitive_neverlink_jars)
         add_exports.append(p.module_flags_info.add_exports)
         add_opens.append(p.module_flags_info.add_opens)
         _neverlink = _neverlink or p._neverlink
@@ -154,6 +156,7 @@
         "full_compile_jars": depset(order = "preorder", transitive = full_compile_jars),
         "_transitive_full_compile_time_jars": depset(order = "preorder", transitive = _transitive_full_compile_time_jars),
         "_compile_time_java_dependencies": depset(order = "preorder", transitive = _compile_time_java_dependencies),
+        "_transitive_neverlink_jars": depset(order = "preorder", transitive = _transitive_neverlink_jars),
         # runtime_output_jars is a list so we uniquify to avoid https://github.com/bazelbuild/bazel/issues/17170
         "runtime_output_jars": depset(runtime_output_jars).to_list(),
         # source_jars is a list so we uniquify to avoid https://github.com/bazelbuild/bazel/issues/17170
@@ -206,6 +209,7 @@
         "full_compile_jars": depset(),
         "_transitive_full_compile_time_jars": depset(),
         "_compile_time_java_dependencies": depset(),
+        "_transitive_neverlink_jars": depset(),
         "runtime_output_jars": [],
         "plugins": _EMPTY_PLUGIN_DATA,
         "api_generating_plugins": _EMPTY_PLUGIN_DATA,
@@ -263,6 +267,10 @@
         "full_compile_jars": java_info.full_compile_jars,
         "_transitive_full_compile_time_jars": java_info._transitive_full_compile_time_jars,
         "_compile_time_java_dependencies": java_info._compile_time_java_dependencies,
+        "_transitive_neverlink_jars": depset(
+            order = "preorder",
+            transitive = [java_info.transitive_runtime_jars, java_info._transitive_neverlink_jars],
+        ) if neverlink else java_info._transitive_neverlink_jars,
         "_neverlink": neverlink,
         # unset defaults
         "source_jars": [],
@@ -477,19 +485,11 @@
         generated_source_jar,
         native_libraries,
         neverlink,
+        direct_runtime_jars,
         header_compilation_jar,
     )
 
-    # this differs ever so slightly from the usual JavaInfo in that direct_runtime_jars
-    # does not contain the output_jar is there were no sources/resources
-    transitive_runtime_jars = depset() if neverlink else depset(
-        order = "preorder",
-        direct = direct_runtime_jars,
-        transitive = [dep.transitive_runtime_jars for dep in concatenated_deps.exports_deps + runtime_deps],
-    )
     result.update(
-        runtime_output_jars = direct_runtime_jars,
-        transitive_runtime_jars = transitive_runtime_jars,
         transitive_source_jars = depset(
             direct = [source_jar] if source_jar else [],
             # only differs from the usual java_info.transitive_source_jars in the order of deps
@@ -570,6 +570,7 @@
         generated_source_jar,
         native_libraries,
         neverlink,
+        direct_runtime_jars,
         header_compilation_jar = None):
     _validate_provider_list(deps, "deps", JavaInfo)
     _validate_provider_list(runtime_deps, "runtime_deps", JavaInfo)
@@ -590,6 +591,20 @@
         direct = [compile_jar] if compile_jar else [],
         transitive = [dep.transitive_compile_time_jars for dep in concatenated_deps.exports_deps],
     )
+
+    # For java_info_for_compilation, direct_runtime_jars does not contain the
+    # output_jar if there were no sources/resources.
+    runtime_jars = depset(
+        order = "preorder",
+        direct = direct_runtime_jars,
+        transitive = [dep.transitive_runtime_jars for dep in concatenated_deps.exports_deps + runtime_deps],
+    )
+    transitive_runtime_jars = depset() if neverlink else runtime_jars
+    _transitive_neverlink_jars = depset(
+        order = "preorder",
+        transitive = ([runtime_jars] if neverlink else []) +
+                     [dep._transitive_neverlink_jars for dep in concatenated_deps.runtimedeps_exports_deps],
+    )
     java_outputs = [_JavaOutputInfo(
         class_jar = output_jar,
         compile_jar = compile_jar,
@@ -605,6 +620,8 @@
         source_jar = source_jar,  # deprecated
     )]
     result = {
+        "transitive_runtime_jars": transitive_runtime_jars,
+        "_transitive_neverlink_jars": _transitive_neverlink_jars,
         "transitive_compile_time_jars": transitive_compile_time_jars,
         "compile_jars": depset(
             order = "preorder",
@@ -625,7 +642,7 @@
             ],
         ),
         "source_jars": source_jars,
-        "runtime_output_jars": [output_jar],
+        "runtime_output_jars": direct_runtime_jars,
         "plugins": plugin_info.plugins,
         "api_generating_plugins": plugin_info.api_generating_plugins,
         "java_outputs": java_outputs,
@@ -774,18 +791,10 @@
         generated_source_jar,
         native_libraries,
         neverlink,
+        [output_jar],
         header_compilation_jar = header_compilation_jar,
     )
 
-    if neverlink:
-        transitive_runtime_jars = depset()
-    else:
-        transitive_runtime_jars = depset(
-            order = "preorder",
-            direct = [output_jar],
-            transitive = [dep.transitive_runtime_jars for dep in concatenated_deps.exports_deps + runtime_deps],
-        )
-
     # For backward compatibility, we use deps_exports for add_exports/add_opens
     # for the JavaInfo constructor rather than runtimedeps_exports_deps (used
     # by java_info_for_compilation). However, runtimedeps_exports_deps makes
@@ -799,7 +808,6 @@
         module_flags_deps = concatenated_deps.runtimedeps_exports_deps
 
     result.update(
-        transitive_runtime_jars = transitive_runtime_jars,
         transitive_source_jars = depset(
             direct = [source_jar] if source_jar else [],
             # TODO(hvd): native also adds source jars from deps, but this should be unnecessary
@@ -878,6 +886,7 @@
                Java/Java-like target.""",
         "_transitive_full_compile_time_jars": "internal API, do not use",
         "_compile_time_java_dependencies": "internal API, do not use",
+        "_transitive_neverlink_jars": "internal API, do not use",
         "_neverlink": "internal API, do not use",
         "_constraints": "internal API, do not use",
         "_is_binary": "internal API, do not use",
diff --git a/test/java/common/java_common_tests.bzl b/test/java/common/java_common_tests.bzl
index e9942ab..4091dee 100644
--- a/test/java/common/java_common_tests.bzl
+++ b/test/java/common/java_common_tests.bzl
@@ -967,8 +967,26 @@
     target_name = name + "/custom"
     util.helper_target(
         java_library,
+        name = target_name + "/transitive_dep",
+        srcs = ["Transitive.java"],
+    )
+    util.helper_target(
+        java_library,
         name = target_name + "/neverlink_dep",
         srcs = ["B.java"],
+        deps = [target_name + "/transitive_dep"],
+        neverlink = True,
+    )
+    util.helper_target(
+        java_library,
+        name = target_name + "/neverlink_rdep",
+        srcs = ["C.java"],
+        neverlink = True,
+    )
+    util.helper_target(
+        java_library,
+        name = target_name + "/neverlink_export",
+        srcs = ["D.java"],
         neverlink = True,
     )
     util.helper_target(
@@ -976,6 +994,8 @@
         name = target_name,
         srcs = ["A.java"],
         deps = [target_name + "/neverlink_dep"],
+        runtime_deps = [target_name + "/neverlink_rdep"],
+        exports = [target_name + "/neverlink_export"],
     )
 
     analysis_test(
@@ -991,11 +1011,65 @@
     ])
     assert_java_info.transitive_source_jars().contains_exactly([
         "{package}/lib{name}-src.jar",
+        "{package}/lib{name}/neverlink_rdep-src.jar",
+        "{package}/lib{name}/neverlink_export-src.jar",
         "{package}/lib{name}/neverlink_dep-src.jar",
+        "{package}/lib{name}/transitive_dep-src.jar",
     ])
     assert_java_info.compilation_args().transitive_compile_time_jars().contains_exactly([
         "{package}/lib{name}-hjar.jar",
+        "{package}/lib{name}/neverlink_export-hjar.jar",
         "{package}/lib{name}/neverlink_dep-hjar.jar",
+        "{package}/lib{name}/transitive_dep-hjar.jar",
+    ])
+    assert_java_info.transitive_neverlink_jars().contains_exactly([
+        "{package}/lib{name}/neverlink_rdep.jar",
+        "{package}/lib{name}/neverlink_export.jar",
+        "{package}/lib{name}/neverlink_dep.jar",
+        "{package}/lib{name}/transitive_dep.jar",
+    ])
+
+def _test_compile_neverlink_with_deps_runtime_deps_and_exports(name):
+    target_name = name + "/custom"
+    util.helper_target(
+        java_library,
+        name = target_name + "/lib_dep",
+        srcs = ["B.java"],
+    )
+    util.helper_target(
+        java_library,
+        name = target_name + "/lib_rdep",
+        srcs = ["C.java"],
+    )
+    util.helper_target(
+        java_library,
+        name = target_name + "/lib_export",
+        srcs = ["D.java"],
+    )
+    util.helper_target(
+        custom_library,
+        name = target_name,
+        srcs = ["A.java"],
+        deps = [target_name + "/lib_dep"],
+        runtime_deps = [target_name + "/lib_rdep"],
+        exports = [target_name + "/lib_export"],
+        neverlink = True,
+    )
+
+    analysis_test(
+        name = name,
+        impl = _test_compile_neverlink_with_deps_runtime_deps_and_exports_impl,
+        target = target_name,
+    )
+
+def _test_compile_neverlink_with_deps_runtime_deps_and_exports_impl(env, target):
+    assert_java_info = java_info_subject.from_target(env, target)
+    assert_java_info.compilation_args().transitive_runtime_jars().contains_exactly([])
+    assert_java_info.transitive_neverlink_jars().contains_exactly([
+        "{package}/lib{name}.jar",
+        "{package}/lib{name}/lib_export.jar",
+        "{package}/lib{name}/lib_dep.jar",
+        "{package}/lib{name}/lib_rdep.jar",
     ])
 
 def _test_compile_output_jar_not_in_runtime_path_without_sources_defined(name):
@@ -1147,6 +1221,7 @@
             _test_strict_java_deps_error,
             _test_compile_output_jar_has_manifest_proto,
             _test_compile_with_neverlink_deps,
+            _test_compile_neverlink_with_deps_runtime_deps_and_exports,
             _test_compile_output_jar_not_in_runtime_path_without_sources_defined,
             _test_java_runtime_provider_files,
             _test_custom_library_with_wrong_java_toolchain_type,
diff --git a/test/java/common/java_info_tests.bzl b/test/java/common/java_info_tests.bzl
index 8f4c2c1..497e1f8 100644
--- a/test/java/common/java_info_tests.bzl
+++ b/test/java/common/java_info_tests.bzl
@@ -200,11 +200,16 @@
     )
 
 def _with_deps_and_neverlink_test_impl(env, target):
-    assert_compilation_args = java_info_subject.from_target(env, target).compilation_args()
+    assert_java_info = java_info_subject.from_target(env, target)
+    assert_compilation_args = assert_java_info.compilation_args()
 
     assert_compilation_args.compile_jars().contains_exactly(["{package}/{name}/my_starlark_rule_lib.jar"])
     assert_compilation_args.full_compile_jars().contains_exactly(["{package}/{name}/my_starlark_rule_lib.jar"])
     assert_compilation_args.transitive_runtime_jars().contains_exactly([])
+    assert_java_info.transitive_neverlink_jars().contains_exactly([
+        "{package}/{name}/my_starlark_rule_lib.jar",
+        "{package}/lib{name}/my_java_lib_direct.jar",
+    ])
     assert_compilation_args.transitive_compile_time_jars().contains_exactly([
         "{package}/{name}/my_starlark_rule_lib.jar",
         "{package}/lib{name}/my_java_lib_direct-hjar.jar",
@@ -1302,7 +1307,103 @@
     )
 
 def _java_common_merge_with_neverlink_test_impl(env, target):
-    java_info_subject.from_target(env, target).is_neverlink().equals(True)
+    assert_java_info = java_info_subject.from_target(env, target)
+    assert_java_info.is_neverlink().equals(True)
+    assert_java_info.compilation_args().transitive_runtime_jars().contains_exactly([
+        "{package}/{name}/without_neverlink.jar",
+    ])
+    assert_java_info.transitive_neverlink_jars().contains_exactly([
+        "{package}/{name}/with_neverlink.jar",
+    ])
+
+def _with_neverlink_and_all_dep_attributes_test(name):
+    target_name = name + "/my_starlark_rule"
+    util.helper_target(
+        java_library,
+        name = target_name + "/lib_dep",
+        srcs = ["java/A.java"],
+    )
+    util.helper_target(
+        java_library,
+        name = target_name + "/lib_rdep",
+        srcs = ["java/B.java"],
+    )
+    util.helper_target(
+        java_library,
+        name = target_name + "/lib_export",
+        srcs = ["java/C.java"],
+    )
+    util.helper_target(
+        custom_java_info_rule,
+        name = target_name,
+        dep = [target_name + "/lib_dep"],
+        dep_runtime = [target_name + "/lib_rdep"],
+        dep_exports = [target_name + "/lib_export"],
+        output_jar = target_name + "/my_starlark_rule_lib.jar",
+        neverlink = True,
+    )
+
+    analysis_test(
+        name = name,
+        impl = _with_neverlink_and_all_dep_attributes_test_impl,
+        target = target_name,
+    )
+
+def _with_neverlink_and_all_dep_attributes_test_impl(env, target):
+    assert_java_info = java_info_subject.from_target(env, target)
+    assert_java_info.compilation_args().transitive_runtime_jars().contains_exactly([])
+    assert_java_info.transitive_neverlink_jars().contains_exactly([
+        "{package}/{name}/my_starlark_rule_lib.jar",
+        "{package}/lib{name}/lib_export.jar",
+        "{package}/lib{name}/lib_dep.jar",
+        "{package}/lib{name}/lib_rdep.jar",
+    ])
+
+def _with_neverlink_deps_across_attributes_test(name):
+    target_name = name + "/my_starlark_rule"
+    util.helper_target(
+        java_library,
+        name = target_name + "/neverlink_dep",
+        srcs = ["java/A.java"],
+        neverlink = True,
+    )
+    util.helper_target(
+        java_library,
+        name = target_name + "/neverlink_rdep",
+        srcs = ["java/B.java"],
+        neverlink = True,
+    )
+    util.helper_target(
+        java_library,
+        name = target_name + "/neverlink_export",
+        srcs = ["java/C.java"],
+        neverlink = True,
+    )
+    util.helper_target(
+        custom_java_info_rule,
+        name = target_name,
+        dep = [target_name + "/neverlink_dep"],
+        dep_runtime = [target_name + "/neverlink_rdep"],
+        dep_exports = [target_name + "/neverlink_export"],
+        output_jar = target_name + "/my_starlark_rule_lib.jar",
+    )
+
+    analysis_test(
+        name = name,
+        impl = _with_neverlink_deps_across_attributes_test_impl,
+        target = target_name,
+    )
+
+def _with_neverlink_deps_across_attributes_test_impl(env, target):
+    assert_java_info = java_info_subject.from_target(env, target)
+    assert_java_info.compilation_args().transitive_runtime_jars().contains_exactly([
+        "{package}/{name}/my_starlark_rule_lib.jar",
+    ])
+    assert_java_info.transitive_neverlink_jars().contains_exactly([
+        "{package}/lib{name}/neverlink_rdep.jar",
+        "{package}/lib{name}/neverlink_export.jar",
+        "{package}/lib{name}/neverlink_dep.jar",
+    ])
 
 def _java_common_compile_with_neverlink_test(name):
     target_name = name + "/compiled"
@@ -1460,6 +1561,8 @@
             _output_source_jars_returns_depset_test,
             _java_info_constructor_with_neverlink_test,
             _java_common_merge_with_neverlink_test,
+            _with_neverlink_and_all_dep_attributes_test,
+            _with_neverlink_deps_across_attributes_test,
             _java_common_compile_with_neverlink_test,
             _java_common_compile_native_libraries_propagate_test,
             _test_merge_runtime_output_jars,
diff --git a/test/java/private/android_support_tests.bzl b/test/java/private/android_support_tests.bzl
index 8f9bea6..0a3122c 100644
--- a/test/java/private/android_support_tests.bzl
+++ b/test/java/private/android_support_tests.bzl
@@ -23,13 +23,17 @@
 
 def _impl(ctx):
     return [
-        android_support.enable_implicit_sourceless_deps_exports_compatibility(ctx.attr.dep[JavaInfo]),
+        android_support.enable_implicit_sourceless_deps_exports_compatibility(
+            ctx.attr.dep[JavaInfo],
+            neverlink = ctx.attr.neverlink,
+        ),
     ]
 
 my_rule = rule(
     implementation = _impl,
     attrs = {
         "dep": attr.label(),
+        "neverlink": attr.bool(),
     },
 )
 
@@ -50,6 +54,12 @@
         name = "transformed",
         dep = ":base",
     )
+    util.helper_target(
+        my_rule,
+        name = "transformed_neverlink",
+        dep = ":base",
+        neverlink = True,
+    )
 
     analysis_test(
         name = name,
@@ -57,15 +67,21 @@
         targets = {
             "base": Label(":base"),
             "transformed": Label(":transformed"),
+            "transformed_neverlink": Label(":transformed_neverlink"),
         },
     )
 
 def _test_enable_implicit_sourceless_deps_exports_compatibility_impl(env, targets):
     base_info = java_info_subject.from_target(env, targets.base)
     transformed_info = java_info_subject.from_target(env, targets.transformed)
+    transformed_neverlink_info = java_info_subject.from_target(env, targets.transformed_neverlink)
     transformed_info.compilation_args().equals_subject(base_info.compilation_args())
     base_info.plugins().processor_jars().contains_exactly(["{package}/libmy_plugin.jar"])
     transformed_info.plugins().processor_jars().contains_exactly([])
+    transformed_info.transitive_neverlink_jars().contains_exactly([])
+    transformed_neverlink_info.is_neverlink().equals(True)
+    transformed_neverlink_info.compilation_args().transitive_runtime_jars().contains_exactly([])
+    transformed_neverlink_info.transitive_neverlink_jars().contains_exactly(["{package}/libbase.jar"])
 
 def android_support_tests(name):
     test_suite(
diff --git a/test/java/testutil/java_info_subject.bzl b/test/java/testutil/java_info_subject.bzl
index 8df4f78..bf6dbb7 100644
--- a/test/java/testutil/java_info_subject.bzl
+++ b/test/java/testutil/java_info_subject.bzl
@@ -26,6 +26,7 @@
         transitive_source_jars = lambda: subjects.depset_file(java_info.transitive_source_jars, self.meta.derive("transitive_source_jars")),
         transitive_source_jars_list = lambda: subjects.collection(java_info.transitive_source_jars.to_list(), self.meta.derive("transitive_source_jars.to_list()")),
         runtime_output_jars = lambda: subjects.depset_file(java_info.runtime_output_jars, self.meta.derive("runtime_output_jars")),
+        transitive_neverlink_jars = lambda: subjects.depset_file(java_info._transitive_neverlink_jars, self.meta.derive("_transitive_neverlink_jars")),
         module_flags = lambda: _new_java_module_flags_subject(self.actual, self.meta),
         is_neverlink = lambda: subjects.bool(getattr(java_info, "_neverlink", False), self.meta.derive("_neverlink")),
     )