src/app/clusters/actions-server/tests/BUILD.gn

# Copyright (c) 2026 Project CHIP Authors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build_overrides/build.gni")
import("//build_overrides/chip.gni")
import("//build_overrides/pigweed.gni")

import("${chip_root}/build/chip/chip_test_suite.gni")

source_set("actions-cluster-test-srcs") {
  sources = [
    "${chip_root}/src/app/clusters/actions-server/CodegenIntegration.cpp",
    "${chip_root}/src/app/clusters/actions-server/CodegenIntegration.h",
    "${chip_root}/src/app/clusters/actions-server/actions-server.h",
    "${chip_root}/zzz_generated/app-common/app-common/zap-generated/attributes/Accessors.cpp",
  ]

  public_deps = [
    "${chip_root}/src/app/clusters/actions-server",
    "${chip_root}/src/app/common:cluster-objects",
    "${chip_root}/src/app/util/mock:mock_codegen_data_model",
    "${chip_root}/src/lib/core",
  ]
}

chip_test_suite("tests") {
  output_name = "libTestCodeDrivenActionsCluster"

  test_sources = [ "TestActionsCluster.cpp" ]

  public_deps = [
    "${chip_root}/src/app/clusters/actions-server",
    "${chip_root}/src/app/server-cluster/testing:testing",
  ]

  cflags = [ "-Wconversion" ]
}

chip_test_suite("tests-backwards-compatibility") {
  import(
      "${chip_root}/src/app/clusters/actions-server/app_config_dependent_sources.gni")

  output_name = "libTestActionsClusterBackwardsCompatibility"

  test_sources = [ "TestActionsClusterBackwardCompatability.cpp" ]

  sources = []
  foreach(file, app_config_dependent_sources) {
    sources += [ "../" + file ]
  }

  public_deps = [
    "${chip_root}/src/app/clusters/actions-server",
    "${chip_root}/src/app/common:cluster-objects",
    "${chip_root}/src/app/server-cluster/testing:testing",
    "${chip_root}/src/app/tests:app-test-stubs",
    "${chip_root}/src/app/util/mock:mock_codegen_data_model",
    "${chip_root}/src/lib/core",
    "${chip_root}/src/protocols",  # Awkward, because Sessionmanager layering
                                   # issues.
  ]
}