src/app/clusters/zone-management-server/tests/BUILD.gn

# Copyright (c) 2025 Project CHIP Authors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build_overrides/build.gni")
import("//build_overrides/chip.gni")
import("//build_overrides/pigweed.gni")

import("${chip_root}/build/chip/chip_test_suite.gni")

chip_test_suite("tests") {
  output_name = "TestZoneManagement"

  test_sources = [
    "TestZoneManagementCluster.cpp",
    "TestZonePolygon.cpp",
  ]

  cflags = [ "-Wconversion" ]

  public_deps = [
    "${chip_root}/src/app/clusters/zone-management-server",
    "${chip_root}/src/app/server-cluster/testing",
    "${chip_root}/src/app/server-cluster/testing:testing",
    "${chip_root}/src/lib/support",
  ]
}

chip_test_suite("tests-backwards-compatibility") {
  import(
      "${chip_root}/src/app/clusters/zone-management-server/app_config_dependent_sources.gni")

  output_name = "TestZoneManagementClusterBackwardsCompatibility"

  test_sources = [ "TestZoneManagementClusterBackwardsCompatibility.cpp" ]

  # Prefix app_config_dependent_sources with "../" and add to the sources list.
  sources = []
  foreach(file, app_config_dependent_sources) {
    sources += [ "../" + file ]
  }

  cflags = [ "-Wconversion" ]

  public_deps = [
    "${chip_root}/src/app/clusters/zone-management-server",
    "${chip_root}/src/app/server-cluster/testing",
    "${chip_root}/src/app/server-cluster/testing:testing",
    "${chip_root}/src/data-model-providers/codegen/tests:mock_model",
    "${chip_root}/src/lib/support",
  ]
}